Timer with a pause and resume

package tv.agenciaperu.utils {

import flash.utils.Timer;
import flash.events.TimerEvent;

public class TimerAdv extends Timer {

private var $__initDelay:Number = 0;
private var $__pauseTime:Number = 0;
private var $__acumulado:Number = 0;
private var $__startingTime:Number = NaN;
private var $__paused:Boolean = false;

public function TimerAdv(delay:Number, repeatCount:uint = 0){
$__initDelay = delay;
super(delay, repeatCount);
}

public function get paused():Boolean{ return $__paused; }

override public function start():void{
$__startingTime = new Date().getTime();
super.start();
}

override public function reset():void{
delay = $__initDelay;
$__acumulado = 0;
$__pauseTime = 0;
super.reset();
}

public function pause():void{
super.stop();
$__paused = true;
$__pauseTime = new Date().getTime();
if(isNaN($__startingTime)) $__startingTime = $__pauseTime;
}

public function resume():void{
$__paused = false;
delay = Math.max(0, ($__initDelay - (($__pauseTime - $__startingTime) + $__acumulado)));
$__acumulado += ($__pauseTime - $__startingTime);
addEventListener(TimerEvent.TIMER, restoreInitDelay, false, 0, true);
start();
}

private function restoreInitDelay(e:TimerEvent):void{
removeEventListener(e.type, arguments.callee);
delay = $__initDelay;
$__acumulado = 0;
$__pauseTime = 0;
}

}

}

Let me know if you find a bug plz so i can update the post.

--fernando

Update 1: Fixed a bug in the delay value for future repetitions